# Maintainer: Cametendo cameronmathis08@gmail.com
pkgname=cflash
pkgver=1.0.1
pkgrel=1
pkgdesc="A small and lightweight wrapper for dd that strips away the complexity of CLI flashing."
arch=('any')
url="https://gitea.cametendo.org/cametendo/cflash-emvs"
license=('MIT') 
depends=('java-runtime>=21')
makedepends=('java-environment>=21' 'maven' 'git')
source=("cflash::git+https://gitea.cametendo.org/cametendo/cflash-emvs.git")
sha256sums=('SKIP')
install=cflash.install

build() {
  cd "$pkgname"
  # using 'package' because pom.xml triggers the assembly plugin during this phase
  mvn clean package
}

package() {
  cd "$srcdir/cflash"
  
	install -Dm644 "target/${pkgname}-${pkgver}-jar-with-dependencies.jar" \
	"$pkgdir/usr/share/java/${pkgname}/${pkgname}.jar"

  # Create the executable
  install -d "$pkgdir/usr/bin"
  cat <<EOF > "$pkgdir/usr/bin/cflash"
#!/bin/sh
exec /usr/bin/java -jar /usr/share/java/cflash/cflash.jar "\$@"
EOF
  # makes the program executable
  chmod +x "$pkgdir/usr/bin/cflash"
}